" vim600: set foldmethod=marker:

"

" Vim plugin to assist in working with CVS-controlled files.

"

" Last Change:   2006/02/22

" Version:       1.76

" Maintainer:    Bob Hiestand <bob.hiestand@gmail.com>

" License:       This file is placed in the public domain.

" Credits: {{{1

"                Mathieu Clabaut for many suggestions and improvements.

"

"                Suresh Govindachar and Jeeva Chelladhurai for finding waaaay

"                too many bugs.

"

"                Suresh Govindachar (again!) for finding the

"                fully-folded-last-line-delete bug.

"

"                Albrecht Gass for the Delete-on-Hide behavior suggestion.

"

"                Joe MacDonald for finding the CVS log message header bug and

"                pointing out that buffer refreshes are needed after CVS

"                \%(un\)\?edit.

"

"                Srinath Avadhanula for the suggestion and original patch for

"                the CVSCommitOnWrite option and mapping hot key.

"

"                John Sivak for helping to debug Windows issues and suggesting

"                the CVSEditors and CVSWatchers commands.

"

"                Igor Levko for the patch to recognize numerical sticky tags.

"

"                Domink Strasser for the patch to correct the status line for

"                CVSAdd'd files.

"

"                Weerapong Sirikanya for finding a bug with CVSCommit and

"                autochdir.

"

"                David Gotz for finding a bug with CVSVimDiff buffer splitting

"                and original buffer restoration.

"

"                CJ van den Berg for the patch to not change working directory

"                when editing a non-CVS file.

"

"                Luca Gerli for noticing bad behavior for keywords in files

"                after commit if split windows are used.

" Section: Documentation {{{1

"

" Provides functions to invoke various CVS commands on the current file

" (either the current buffer, or, in the case of an directory buffer, the file

" on the current line).  The output of the commands is captured in a new

" scratch window.  For convenience, if the functions are invoked on a CVS

" output window, the original file is used for the cvs operation instead after

" the window is split.  This is primarily useful when running CVSCommit and

" you need to see the changes made, so that CVSDiff is usable and shows up in

" another window.

"

" Command documentation {{{2

"

" CVSAdd           Performs "cvs add" on the current file.

"

" CVSAnnotate      Performs "cvs annotate" on the current file.  If an

"                  argument is given, the argument is used as a revision

"                  number to display.  If not given an argument, it uses the

"                  most recent version of the file on the current branch.

"                  Additionally, if the current buffer is a CVSAnnotate buffer

"                  already, the version number on the current line is used.

"

"                  If the 'CVSCommandAnnotateParent' variable is set to a

"                  non-zero value, the version previous to the one on the

"                  current line is used instead.  This allows one to navigate

"                  back to examine the previous version of a line.

"

" CVSCommit[!]     If called with arguments, this performs "cvs commit" using

"                  the arguments as the log message.

"

"                  If '!' is used, an empty log message is committed.

"

"                  If called with no arguments, this is a two-step command.

"                  The first step opens a buffer to accept a log message.

"                  When that buffer is written, it is automatically closed and

"                  the file is committed using the information from that log

"                  message.  The commit can be abandoned if the log message

"                  buffer is deleted or wiped before being written.

"

" CVSDiff          With no arguments, this performs "cvs diff" on the current

"                  file.  With one argument, "cvs diff" is performed on the

"                  current file against the specified revision.  With two

"                  arguments, cvs diff is performed between the specified

"                  revisions of the current file.  This command uses the

"                  'CVSCommandDiffOpt' variable to specify diff options.  If

"                  that variable does not exist, then 'wbBc' is assumed.  If

"                  you wish to have no options, then set it to the empty

"                  string.

"

" CVSEdit          Performs "cvs edit" on the current file.

"

" CVSEditors       Performs "cvs editors" on the current file.

"

" CVSGotoOriginal  Returns the current window to the source buffer if the

"                  current buffer is a CVS output buffer.

"

" CVSLog           Performs "cvs log" on the current file.

"

" CVSRevert        Replaces the modified version of the current file with the

"                  most recent version from the repository.

"

" CVSReview        Retrieves a particular version of the current file.  If no

"                  argument is given, the most recent version of the file on

"                  the current branch is retrieved.  The specified revision is

"                  retrieved into a new buffer.

"

" CVSStatus        Performs "cvs status" on the current file.

"

" CVSUnedit        Performs "cvs unedit" on the current file.

"

" CVSUpdate        Performs "cvs update" on the current file.

"

" CVSVimDiff       With no arguments, this prompts the user for a revision and

"                  then uses vimdiff to display the differences between the

"                  current file and the specified revision.  If no revision is

"                  specified, the most recent version of the file on the

"                  current branch is used.  With one argument, that argument

"                  is used as the revision as above.  With two arguments, the

"                  differences between the two revisions is displayed using

"                  vimdiff.

"

"                  With either zero or one argument, the original buffer is used

"                  to perform the vimdiff.  When the other buffer is closed, the

"                  original buffer will be returned to normal mode.

"

"                  Once vimdiff mode is started using the above methods,

"                  additional vimdiff buffers may be added by passing a single

"                  version argument to the command.  There may be up to 4

"                  vimdiff buffers total.

"

"                  Using the 2-argument form of the command resets the vimdiff

"                  to only those 2 versions.  Additionally, invoking the

"                  command on a different file will close the previous vimdiff

"                  buffers.

"

" CVSWatch         Takes an argument which must be one of [on|off|add|remove].

"                  Performs "cvs watch" with the given argument on the current

"                  file.

"

" CVSWatchers      Performs "cvs watchers" on the current file.

"

" CVSWatchAdd      Alias for "CVSWatch add"

"

" CVSWatchOn       Alias for "CVSWatch on"

"

" CVSWatchOff      Alias for "CVSWatch off"

"

" CVSWatchRemove   Alias for "CVSWatch remove"

"

" Mapping documentation: {{{2

"

" By default, a mapping is defined for each command.  User-provided mappings

" can be used instead by mapping to <Plug>CommandName, for instance:

"

" nnoremap ,ca <Plug>CVSAdd

"

" The default mappings are as follow:

"

"   <Leader>ca CVSAdd

"   <Leader>cn CVSAnnotate

"   <Leader>cc CVSCommit

"   <Leader>cd CVSDiff

"   <Leader>ce CVSEdit

"   <Leader>ci CVSEditors

"   <Leader>cg CVSGotoOriginal

"   <Leader>cG CVSGotoOriginal!

"   <Leader>cl CVSLog

"   <Leader>cr CVSReview

"   <Leader>cs CVSStatus

"   <Leader>ct CVSUnedit

"   <Leader>cu CVSUpdate

"   <Leader>cv CVSVimDiff

"   <Leader>cwv CVSWatchers

"   <Leader>cwa CVSWatchAdd

"   <Leader>cwn CVSWatchOn

"   <Leader>cwa CVSWatchOff

"   <Leader>cwr CVSWatchRemove

"

" Options documentation: {{{2

"

" Several variables are checked by the script to determine behavior as follow:

"

" CVSCommandAnnotateParent

"   This variable, if set to a non-zero value, causes the zero-argument form

"   of CVSAnnotate when invoked on a CVSAnnotate buffer to go to the version

"   previous to that displayed on the current line.  If not set, it defaults

"   to 0.

"

" CVSCommandCommitOnWrite

"   This variable, if set to a non-zero value, causes the pending cvs commit

"   to take place immediately as soon as the log message buffer is written.

"   If set to zero, only the CVSCommit mapping will cause the pending commit

"   to occur.  If not set, it defaults to 1.

"

" CVSCommandDeleteOnHide

"   This variable, if set to a non-zero value, causes the temporary CVS result

"   buffers to automatically delete themselves when hidden.

"

" CVSCommandDiffOpt

"   This variable, if set, determines the options passed to the diff command

"   of CVS.  If not set, it defaults to 'wbBc'.

"

" CVSCommandDiffSplit

"   This variable overrides the CVSCommandSplit variable, but only for buffers

"   created with CVSVimDiff.

"

" CVSCommandEdit

"   This variable controls whether the original buffer is replaced ('edit') or

"   split ('split').  If not set, it defaults to 'edit'.

"

" CVSCommandEnableBufferSetup

"   This variable, if set to a non-zero value, activates CVS buffer management

"   mode.  This mode means that two buffer variables, 'CVSRevision' and

"   'CVSBranch', are set if the file is CVS-controlled.  This is useful for

"   displaying version information in the status bar.

"

" CVSCommandInteractive

"   This variable, if set to a non-zero value, causes appropriate functions (for

"   the moment, only CVSReview) to query the user for a revision to use

"   instead of the current revision if none is specified.

"

" CVSCommandNameMarker

"   This variable, if set, configures the special attention-getting characters

"   that appear on either side of the cvs buffer type in the buffer name.

"   This has no effect unless 'CVSCommandNameResultBuffers' is set to a true

"   value.  If not set, it defaults to '_'.  

"

" CVSCommandNameResultBuffers

"   This variable, if set to a true value, causes the cvs result buffers to be

"   named in the old way ('<source file name> _<cvs command>_').  If not set

"   or set to a false value, the result buffer is nameless.

"

" CVSCommandSplit

"   This variable controls the orientation of the various window splits that

"   may occur (such as with CVSVimDiff, when using a CVS command on a CVS

"   command buffer, or when the 'CVSCommandEdit' variable is set to 'split'.

"   If set to 'horizontal', the resulting windows will be on stacked on top of

"   one another.  If set to 'vertical', the resulting windows will be

"   side-by-side.  If not set, it defaults to 'horizontal' for all but

"   CVSVimDiff windows.

"

" Event documentation {{{2

"   For additional customization, cvscommand.vim uses User event autocommand

"   hooks.  Each event is in the CVSCommand group, and different patterns

"   match the various hooks.

"

"   For instance, the following could be added to the vimrc to provide a 'q'

"   mapping to quit a CVS buffer:

"

"   augroup CVSCommand

"     au CVSCommand User CVSBufferCreated silent! nmap <unique> <buffer> q :bwipeout<cr> 

"   augroup END

"

"   The following hooks are available:

"

"   CVSBufferCreated           This event is fired just after a cvs command

"                              result buffer is created and filled with the

"                              result of a cvs command.  It is executed within

"                              the context of the new buffer.

"

"   CVSBufferSetup             This event is fired just after CVS buffer setup

"                              occurs, if enabled.

"

"   CVSPluginInit              This event is fired when the CVSCommand plugin

"                              first loads.

"

"   CVSPluginFinish            This event is fired just after the CVSCommand

"                              plugin loads.

"

"   CVSVimDiffFinish           This event is fired just after the CVSVimDiff

"                              command executes to allow customization of,

"                              for instance, window placement and focus.

"

" Section: Plugin header {{{1

" loaded_cvscommand is set to 1 when the initialization begins, and 2 when it

" completes.  This allows various actions to only be taken by functions after

" system initialization.

if exists("loaded_cvscommand")

   finish

endif

let loaded_cvscommand = 1

if v:version < 602

  echohl WarningMsg|echomsg "CVSCommand 1.69 or later requires VIM 6.2 or later"|echohl None

  finish

endif

" Section: Event group setup {{{1

augroup CVSCommand

augroup END

" Section: Plugin initialization {{{1

silent do CVSCommand User CVSPluginInit

" Section: Script variable initialization {{{1

let s:CVSCommandEditFileRunning = 0

unlet! s:vimDiffRestoreCmd

unlet! s:vimDiffSourceBuffer

unlet! s:vimDiffBufferCount

unlet! s:vimDiffScratchList

" Section: Utility functions {{{1

" Function: s:CVSResolveLink() {{{2

" Fully resolve the given file name to remove shortcuts or symbolic links.

function! s:CVSResolveLink(fileName)

  let resolved = resolve(a:fileName)

  if resolved != a:fileName

    let resolved = s:CVSResolveLink(resolved)

  endif

  return resolved

endfunction

" Function: s:CVSChangeToCurrentFileDir() {{{2

" Go to the directory in which the current CVS-controlled file is located.

" If this is a CVS command buffer, first switch to the original file.

function! s:CVSChangeToCurrentFileDir(fileName)

  let oldCwd=getcwd()

  let fileName=s:CVSResolveLink(a:fileName)

  let newCwd=fnamemodify(fileName, ':h')

  if strlen(newCwd) > 0

    execute 'cd' escape(newCwd, ' ')

  endif

  return oldCwd

endfunction

" Function: s:CVSGetOption(name, default) {{{2

" Grab a user-specified option to override the default provided.  Options are

" searched in the window, buffer, then global spaces.

function! s:CVSGetOption(name, default)

  if exists("s:" . a:name . "Override")

    execute "return s:".a:name."Override"

  elseif exists("w:" . a:name)

    execute "return w:".a:name

  elseif exists("b:" . a:name)

    execute "return b:".a:name

  elseif exists("g:" . a:name)

    execute "return g:".a:name

  else

    return a:default

  endif

endfunction

" Function: s:CVSEditFile(name, origBuffNR) {{{2

" Wrapper around the 'edit' command to provide some helpful error text if the

" current buffer can't be abandoned.  If name is provided, it is used;

" otherwise, a nameless scratch buffer is used.

" Returns: 0 if successful, -1 if an error occurs.

function! s:CVSEditFile(name, origBuffNR)

  "Name parameter will be pasted into expression.

  let name = escape(a:name, ' *?\')

  let editCommand = s:CVSGetOption('CVSCommandEdit', 'edit')

  if editCommand != 'edit'

    if s:CVSGetOption('CVSCommandSplit', 'horizontal') == 'horizontal'

      if name == ""

        let editCommand = 'rightbelow new'

      else

        let editCommand = 'rightbelow split ' . name

      endif

    else

      if name == ""

        let editCommand = 'vert rightbelow new'

      else

        let editCommand = 'vert rightbelow split ' . name

      endif

    endif

  else

    if name == ""

      let editCommand = 'enew'

    else

      let editCommand = 'edit ' . name

    endif

  endif

  " Protect against useless buffer set-up

  let s:CVSCommandEditFileRunning = s:CVSCommandEditFileRunning + 1

  try

    execute editCommand

  finally

    let s:CVSCommandEditFileRunning = s:CVSCommandEditFileRunning - 1

  endtry

  let b:CVSOrigBuffNR=a:origBuffNR

  let b:CVSCommandEdit='split'

endfunction

" Function: s:CVSCreateCommandBuffer(cmd, cmdName, statusText, filename) {{{2

" Creates a new scratch buffer and captures the output from execution of the

" given command.  The name of the scratch buffer is returned.

function! s:CVSCreateCommandBuffer(cmd, cmdName, statusText, origBuffNR)

  let fileName=bufname(a:origBuffNR)

  let resultBufferName=''

  if s:CVSGetOption("CVSCommandNameResultBuffers", 0)

    let nameMarker = s:CVSGetOption("CVSCommandNameMarker", '_')

    if strlen(a:statusText) > 0

      let bufName=a:cmdName . ' -- ' . a:statusText

    else

      let bufName=a:cmdName

    endif

    let bufName=fileName . ' ' . nameMarker . bufName . nameMarker

    let counter=0

    let resultBufferName = bufName

    while buflisted(resultBufferName)

      let counter=counter + 1

      let resultBufferName=bufName . ' (' . counter . ')'

    endwhile

  endif

  let cvsCommand = s:CVSGetOption("CVSCommandCVSExec", "cvs") . " " . a:cmd

  let cvsOut = system(cvsCommand)

  " HACK:  diff command does not return proper error codes

  if v:shell_error && a:cmdName != 'cvsdiff'

    if strlen(cvsOut) == 0

      echoerr "CVS command failed"

    else

      echoerr "CVS command failed:  " . cvsOut

    endif

    return -1

  endif

  if strlen(cvsOut) == 0

    " Handle case of no output.  In this case, it is important to check the

    " file status, especially since cvs edit/unedit may change the attributes

    " of the file with no visible output.

    echomsg "No output from CVS command"

    checktime

    return -1

  endif

  if s:CVSEditFile(resultBufferName, a:origBuffNR) == -1

    return -1

  endif

  set buftype=nofile

  set noswapfile

  set filetype=

  if s:CVSGetOption("CVSCommandDeleteOnHide", 0)

    set bufhidden=delete

  endif

  silent 0put=cvsOut

  " The last command left a blank line at the end of the buffer.  If the

  " last line is folded (a side effect of the 'put') then the attempt to

  " remove the blank line will kill the last fold.

  "

  " This could be fixed by explicitly detecting whether the last line is

  " within a fold, but I prefer to simply unfold the result buffer altogether.

  if has('folding')

    normal zR

  endif

  $d

  1

  " Define the environment and execute user-defined hooks.

  let b:CVSSourceFile=fileName

  let b:CVSCommand=a:cmdName

  if a:statusText != ""

    let b:CVSStatusText=a:statusText

  endif