pyoxidizer: produce working Python 3 Windows installers (issue6366) While we've had code to produce Python 3 Windows installers with PyOxidizer, we haven't been advertising them on the web site due to a bug in making TLS connections and issues around resource handling. This commit upgrades our PyOxidizer install and configuration to use a recent Git commit of PyOxidizer. This new version of PyOxidizer contains a *ton* of changes, improvements, and bug fixes. Notably, Windows shared distributions now mostly "just work" and the TLS bug and random problems with Python extension modules in the standard library go away. And Python has been upgraded from 3.7 to 3.8.6. The price we pay for this upgrade is a ton of backwards incompatible changes to Starlark. I applied this commit (the overall series actually) on stable to produce Windows installers for Mercurial 5.5.2, which I published shortly before submitting this commit for review. In order to get the stable branch working, I decided to take a less aggressive approach to Python resource management. Previously, we were attempting to load all Python modules from memory and were performing some hacks to copy Mercurial's non-module resources into additional directories in Starlark. This commit implements a resource callback function in Starlark (a new feature since PyOxidizer 0.7) to dynamically assign standard library resources to in-memory loading and all other resources to filesystem loading. This means that Mercurial's files and all the other packages we ship in the Windows installers (e.g. certifi and pygments) are loaded from the filesystem instead of from memory. This avoids issues due to lack of __file__ and enables us to ship a working Python 3 installer on Windows. The end state of the install layout after this patch is not ideal for @: we still copy resource files like templates and help text to directories next to the hg.exe executable. There is code in @ to use importlib.resources to load these files and we could likely remove these copies once this lands on @. But for now, the install layout mimics what we've shipped for seemingly forever and is backwards compatible. It allows us to achieve the milestone of working Python 3 Windows installers and gets us a giant step closer to deleting Python 2. Differential Revision: https://phab.mercurial-scm.org/D9148

     1

ROOT = CWD + "/../.."

     2

     3

IS_WINDOWS = "windows" in BUILD_TARGET_TRIPLE

     4

     5

# Code to run in Python interpreter.

     6

RUN_CODE = "import hgdemandimport; hgdemandimport.enable(); from mercurial import dispatch; dispatch.run()"

     7

     8

set_build_path(ROOT + "/build/pyoxidizer")

     9

    10

def make_distribution():

    11

    return default_python_distribution()

    12

    13

def make_distribution_windows():

    14

    return default_python_distribution(flavor = "standalone_dynamic")

    15

    16

def resource_callback(policy, resource):

    17

    # We use a custom resource routing policy to influence where things are loaded

    18

    # from.

    19

    #

    20

    # For Python modules and resources, we load from memory if they are in

    21

    # the standard library and from the filesystem if not. This is because

    22

    # parts of Mercurial and some 3rd party packages aren't yet compatible

    23

    # with memory loading.

    24

    #

    25

    # For Python extension modules, we load from the filesystem because

    26

    # this yields greatest compatibility.

    27

    if type(resource) in ("PythonModuleSource", "PythonPackageResource", "PythonPackageDistributionResource"):

    28

        if resource.is_stdlib:

    29

            resource.add_location = "in-memory"

    30

        else:

    31

            resource.add_location = "filesystem-relative:lib"

    32

    33

    elif type(resource) == "PythonExtensionModule":

    34

        resource.add_location = "filesystem-relative:lib"

    35

    36

def make_exe(dist):

    37

    """Builds a Rust-wrapped Mercurial binary."""

    38

    packaging_policy = dist.make_python_packaging_policy()

    39

    # Extension may depend on any Python functionality. Include all

    40

    # extensions.

    41

    packaging_policy.extension_module_filter = "all"

    42

    packaging_policy.resources_policy = "prefer-in-memory-fallback-filesystem-relative:lib"

    43

    packaging_policy.register_resource_callback(resource_callback)

    44

    45

    config = PythonInterpreterConfig(

    46

        raw_allocator = "system",

    47

        run_eval = RUN_CODE,

    48

        # We want to let the user load extensions from the file system

    49

        filesystem_importer = True,

    50

        # We need this to make resourceutil happy, since it looks for sys.frozen.

    51

        sys_frozen = True,

    52

        legacy_windows_stdio = True,

    53

    )

    54

    55

    exe = dist.to_python_executable(

    56

        name = "hg",

    57

        packaging_policy = packaging_policy,

    58

        config = config,

    59

    )

    60

    61

    # Add Mercurial to resources.

    62

    exe.add_python_resources(exe.pip_install(["--verbose", ROOT]))

    63

    64

    # On Windows, we install extra packages for convenience.

    65

    if IS_WINDOWS:

    66

        exe.add_python_resources(

    67

            exe.pip_install(["-r", ROOT + "/contrib/packaging/requirements_win32.txt"]),

    68

        )

    69

    70

    return exe

    71

    72

def make_manifest(dist, exe):

    73

    m = FileManifest()

    74

    m.add_python_resource(".", exe)

    75

    76

    return m

    77

    78

def make_embedded_resources(exe):

    79

    return exe.to_embedded_resources()

    80

    81

register_target("distribution_posix", make_distribution)

    82

register_target("distribution_windows", make_distribution_windows)

    83

    84

register_target("exe_posix", make_exe, depends = ["distribution_posix"])

    85

register_target("exe_windows", make_exe, depends = ["distribution_windows"])

    86

    87

register_target(

    88

    "app_posix",

    89

    make_manifest,

    90

    depends = ["distribution_posix", "exe_posix"],

    91

    default = "windows" not in BUILD_TARGET_TRIPLE,

    92

)

    93

register_target(

    94

    "app_windows",

    95

    make_manifest,

    96

    depends = ["distribution_windows", "exe_windows"],

    97

    default = "windows" in BUILD_TARGET_TRIPLE,

    98

)

    99

   100

resolve_targets()

   101

   102

# END OF COMMON USER-ADJUSTED SETTINGS.

   103

#

   104

# Everything below this is typically managed by PyOxidizer and doesn't need

   105

# to be updated by people.

   106

   107

PYOXIDIZER_VERSION = "0.8.0-pre"

   108

PYOXIDIZER_COMMIT = "4697fb25918dfad6dc73288daeea501063963a08"