# Enable my Vim-like mode for supported terms
if [[ "$TERM" == rxvt* ||
      "$TERM" == xterm* ||
      "$TERM" == st-* ||
      "$TERM" == screen* ||
      "$TERM" == tmux* ]]
then
    export SHOWMODE="on"
fi


# __hg_fast_root()
# My shell implementation of fast_hg_root.
# Please let me now if it can be improved.
# Mikael
function __hg_fast_root() {
    local checkdir=$PWD
    local hgdir=".hg"
    while [[ ${checkdir} != '/' ]]; do
        [[ -r ${checkdir} ]] || return 1
        [[ -d ${checkdir}/${hgdir} ]] && return 0
        checkdir=${checkdir}/..
        checkdir="${checkdir:A}"
    done
    #[[ ${checkdir} == '/' ]] && return 1
    return 1
}

# You can use fast_hg_root from https://bitbucket.org/yaniv_aknin/fast_hg_root
# or maybe use the command false if you don't use Mercurial at all.
# You can also use the actual hg command: HG_ROOT_CMD=("hg" "root")
# ... but it will be slow
# (Override in $ZDOTLOCALDIR/zshrc)
HG_ROOT_CMD=(__hg_fast_root)
export HG_ROOT_CMD


### Extended prompts

function __prompt_path_color {
  local path_color
  if [[ -O "$PWD" ]]; then
    path_color="${fg_no_bold[magenta]}"
  elif [[ -w "$PWD" ]]; then
    path_color="${fg_no_bold[blue]}"
  else
    path_color="${fg_bold[red]}"
  fi
  print "%{$path_color%}"
}

# From http://stevelosh.com/blog/2010/02/my-extravagant-zsh-prompt/
function __prompt_char {
    $HG_ROOT_CMD >/dev/null 2>/dev/null && echo '☿' && return
    __gitdir >/dev/null 2>/dev/null && echo '±' && return
    echo '○'
}

function __hg_prompt_info {
    $HG_ROOT_CMD >/dev/null 2>/dev/null && 
    hg prompt --angle-brackets "
<HG patches: <patches|join( → )|pre_applied(%{$fg[yellow]%})|post_applied(%{$reset_color%})|pre_unapplied(%{$fg[cyan]%})|post_unapplied(%{$reset_color%})>
>%BHG%b<(%{$fg[green]%}<status|modified|unknown>%{$reset_color%})><%{$fg[green]%}<update>%{$reset_color%}>\
< on %{$fg[magenta]%}<branch|quiet>%{$reset_color%}>\
< at %{$fg[yellow]%}<tags|%{$reset_color%}, %{$fg[yellow]%}>%{$reset_color%}>" 2>/dev/null
}

source $ZDOTDIR/tools/git-prompt.sh > /dev/null 2>&1
function __git_prompt_info {
  r=$(__git_ps1)
  # If GIT_PS1_SHOWUNTRACKEDFILES is used, we need to escape the %
  r=${r//\%/%%}
  if [[ ! -z $r ]]; then echo -e "\n%Bgit%b$r"; fi
}

function __prompt_set_dev {
    # Prompt complet sur 2 lignes, couleurs, avec un indicateur de dépôt git/hg
    local -a lines pline

    local red="%{$fg[red]%}"
    local cyan="%{$fg[cyan]%}"
    local reset="%{$reset_color%}"

    # 1re ligne
    pline+=( "%D{%m%d} " )              # Date
    pline+=( "$cyan%D{%H:%M}$reset " )  # Time
    pline+=( $(__prompt_path_color) )   # Couleur du chemin dynamique
    pline+=( "%~$reset" )               # Chemin (cwd)
    lines+=( ${(j::)pline} )
    pline=()

    # 2e ligne
    pline+=( "[%B%n%b] " )              # Nom d'utilisateur
    pline+=( "$red%m$reset" )           # Nom de machine
    pline+=( $(__prompt_char) )         # Indicateur de dépôt (hg/git)
    pline+=( "%# " )                    # Invite de commande
    lines+=( ${(j::)pline} )

    export PS1=${(F)lines}
}

function __prompt_set_dev-mikael {
    # Prompt complet sur 2 ou 3 lignes, avec informations sur les dépôts git/hg
    local -a lines pline

    local bred="%{${fg_bold[red]}%}"
    local red="%{$fg[red]%}"
    local cyan="%{$fg[cyan]%}"
    local reset="%{$reset_color%}"

    local return_code="%(?..$cyan!$bred%?$cyan! $reset)"
    local sign="%(!.%{$bred%}.$cyan)%#$reset "

    # 1re ligne
    pline+=( $return_code )             # Code erreur
    pline+=( "%D{%m%d} " )              # Date
    pline+=( "$cyan%D{%H:%M}$reset " )  # Time
    pline+=( $(__prompt_path_color) )   # Couleur du chemin dynamique
    pline+=( "%~$reset" )               # Chemin (cwd)
    lines+=( ${(j::)pline} )
    pline=()

    # 2e ligne
    pline+=( "[%B%n%b] " )              # Nom d'utilisateur
    pline+=( "$red%m$reset" )           # Nom de machine
    [[ -z $_PROMPT__NO_HG_PROMPT ]] &&
      pline+=( "$(__hg_prompt_info)" )  # Informations de dépôt Mercurial
    pline+=( "$(__git_prompt_info)" )   # Informations de dépôt git
    pline+=( $sign )                    # Invite de commande
    lines+=( ${(j::)pline} )

    export PS1=${(F)lines}
}

function precmd {
    case $_PROMPT_DEFINED in
        dev)
            __prompt_set_dev
            ;;
        dev-mikael)
            __prompt_set_dev-mikael
            ;;
        dev-vcsinfo)
            __precmd_vcsinfo
            ;;
        esac
}

function prompt_set_dev-vcsinfo {
    _PROMPT_DEFINED="dev-vcsinfo"
    source $ZDOTDIR/misc/zshrc_vcsinfo
}

function __prompt_unset_dev-vcsinfo {
    if [[ $_PROMPT_DEFINED == "dev-vcsinfo" ]]; then
        zstyle ':vcs_info:*' enable NONE
        unset RPS1
    fi
}

function prompt_set_blackwhite {
    # Prompt complet sur 2 lignes, N&B
    __prompt_unset_dev-vcsinfo
    unsetopt prompt_subst

    export PS1="%D{%m%d %H:%M} %B%~%b
[%B%n%b:%l] %S%m%s%# "

    export _PROMPT_DEFINED="blackwhite"
}

function prompt_set_color {
    # Prompt complet sur 2 lignes, couleurs
    __prompt_unset_dev-vcsinfo
    unsetopt prompt_subst

    PS1="%D{%m%d} %{$fg[cyan]%}%D{%H:%M}%{$reset_color%} "
    PS1=$PS1"%{$fg[magenta]%}%~%{$reset_color%}
[%B%n%b:%l] %{$fg[red]%}%m%{$reset_color%}%# "
    export PS1

    export _PROMPT_DEFINED="color"
}

function prompt_set_dev {
    __prompt_unset_dev-vcsinfo
    export _PROMPT_DEFINED="dev"
}
function prompt_set_dev-mikael {
    __prompt_unset_dev-vcsinfo
    unset _PROMPT__NO_HG_PROMPT
    # Let's check we have the hg-prompt extension
    hg showconfig extensions 2> /dev/null | grep -q "^extensions.prompt=" || {
        print "You need the hg-prompt extension from Steve Losh." >&2
        print "Check http://bitbucket.org/sjl/hg-prompt/" >&2
        _PROMPT__NO_HG_PROMPT=1
    }
    export _PROMPT_DEFINED="dev-mikael"
}


# Invite de commande par défaut
prompt_set_color