1 ; Script generated by the Inno Setup Script Wizard.

     2 ; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

     3 

     4 #ifndef VERSION

     5 #define FileHandle

     6 #define FileLine

     7 #define VERSION = "unknown"

     8 #if FileHandle = FileOpen(SourcePath + "\..\..\mercurial\__version__.py")

     9   #expr FileLine = FileRead(FileHandle)

    10   #expr FileLine = FileRead(FileHandle)

    11   #define VERSION = Copy(FileLine, Pos('"', FileLine)+1, Len(FileLine)-Pos('"', FileLine)-1)

    12 #endif

    13 #if FileHandle

    14   #expr FileClose(FileHandle)

    15 #endif

    16 #pragma message "Detected Version: " + VERSION

    17 #endif

    18 

    19 #ifndef ARCH

    20 #define ARCH = "x86"

    21 #endif

    22 

    23 [Setup]

    24 AppCopyright=Copyright 2005-2019 Matt Mackall and others

    25 AppName=Mercurial

    26 AppVersion={#VERSION}

    27 #if ARCH == "x64"

    28 AppVerName=Mercurial {#VERSION} (64-bit)

    29 OutputBaseFilename=Mercurial-{#VERSION}-x64

    30 ArchitecturesAllowed=x64

    31 ArchitecturesInstallIn64BitMode=x64

    32 #else

    33 AppVerName=Mercurial {#VERSION}

    34 OutputBaseFilename=Mercurial-{#VERSION}

    35 #endif

    36 InfoAfterFile=contrib/win32/postinstall.txt

    37 LicenseFile=COPYING

    38 ShowLanguageDialog=yes

    39 AppPublisher=Matt Mackall and others

    40 AppPublisherURL=https://mercurial-scm.org/

    41 AppSupportURL=https://mercurial-scm.org/

    42 AppUpdatesURL=https://mercurial-scm.org/

    43 AppID={{4B95A5F1-EF59-4B08-BED8-C891C46121B3}

    44 AppContact=mercurial@mercurial-scm.org

    45 DefaultDirName={pf}\Mercurial

    46 SourceDir=..\..

    47 VersionInfoDescription=Mercurial distributed SCM (version {#VERSION})

    48 VersionInfoCopyright=Copyright 2005-2019 Matt Mackall and others

    49 VersionInfoCompany=Matt Mackall and others

    50 InternalCompressLevel=max

    51 SolidCompression=true

    52 SetupIconFile=contrib\win32\mercurial.ico

    53 AllowNoIcons=true

    54 DefaultGroupName=Mercurial

    55 PrivilegesRequired=none

    56 

    57 [Files]

    58 Source: contrib\mercurial.el; DestDir: {app}/Contrib

    59 Source: contrib\vim\*.*; DestDir: {app}/Contrib/Vim

    60 Source: contrib\zsh_completion; DestDir: {app}/Contrib

    61 Source: contrib\bash_completion; DestDir: {app}/Contrib

    62 Source: contrib\tcsh_completion; DestDir: {app}/Contrib

    63 Source: contrib\tcsh_completion_build.sh; DestDir: {app}/Contrib

    64 Source: contrib\hgk; DestDir: {app}/Contrib; DestName: hgk.tcl

    65 Source: contrib\xml.rnc; DestDir: {app}/Contrib

    66 Source: contrib\mercurial.el; DestDir: {app}/Contrib

    67 Source: contrib\mq.el; DestDir: {app}/Contrib

    68 Source: contrib\hgweb.fcgi; DestDir: {app}/Contrib

    69 Source: contrib\hgweb.wsgi; DestDir: {app}/Contrib

    70 Source: contrib\win32\ReadMe.html; DestDir: {app}; Flags: isreadme

    71 Source: contrib\win32\postinstall.txt; DestDir: {app}; DestName: ReleaseNotes.txt

    72 Source: dist\hg.exe; DestDir: {app}; AfterInstall: Touch('{app}\hg.exe.local')

    73 #if ARCH == "x64"

    74 Source: dist\lib\*.dll; Destdir: {app}\lib

    75 Source: dist\lib\*.pyd; Destdir: {app}\lib

    76 #else

    77 Source: dist\w9xpopen.exe; DestDir: {app}

    78 #endif

    79 Source: dist\python*.dll; Destdir: {app}; Flags: skipifsourcedoesntexist

    80 Source: dist\msvc*.dll; DestDir: {app}; Flags: skipifsourcedoesntexist

    81 Source: dist\Microsoft.VC*.CRT.manifest; DestDir: {app}; Flags: skipifsourcedoesntexist

    82 Source: dist\lib\library.zip; DestDir: {app}\lib

    83 Source: dist\add_path.exe; DestDir: {app}

    84 Source: doc\*.html; DestDir: {app}\Docs

    85 Source: doc\style.css; DestDir: {app}\Docs

    86 Source: mercurial\help\*.txt; DestDir: {app}\help

    87 Source: mercurial\help\internals\*.txt; DestDir: {app}\help\internals

    88 Source: mercurial\default.d\*.rc; DestDir: {app}\default.d

    89 Source: mercurial\locale\*.*; DestDir: {app}\locale; Flags: recursesubdirs createallsubdirs skipifsourcedoesntexist

    90 Source: mercurial\templates\*.*; DestDir: {app}\Templates; Flags: recursesubdirs createallsubdirs

    91 Source: CONTRIBUTORS; DestDir: {app}; DestName: Contributors.txt

    92 Source: COPYING; DestDir: {app}; DestName: Copying.txt

    93 

    94 [INI]

    95 Filename: {app}\Mercurial.url; Section: InternetShortcut; Key: URL; String: https://mercurial-scm.org/

    96 Filename: {app}\default.d\editor.rc; Section: ui; Key: editor; String: notepad

    97 

    98 [UninstallDelete]

    99 Type: files; Name: {app}\Mercurial.url

   100 Type: filesandordirs; Name: {app}\default.d

   101 Type: files; Name: "{app}\hg.exe.local"

   102 

   103 [Icons]

   104 Name: {group}\Uninstall Mercurial; Filename: {uninstallexe}

   105 Name: {group}\Mercurial Command Reference; Filename: {app}\Docs\hg.1.html

   106 Name: {group}\Mercurial Configuration Files; Filename: {app}\Docs\hgrc.5.html

   107 Name: {group}\Mercurial Ignore Files; Filename: {app}\Docs\hgignore.5.html

   108 Name: {group}\Mercurial Web Site; Filename: {app}\Mercurial.url

   109 

   110 [Run]

   111 Filename: "{app}\add_path.exe"; Parameters: "{app}"; Flags: postinstall; Description: "Add the installation path to the search path"

   112 

   113 [UninstallRun]

   114 Filename: "{app}\add_path.exe"; Parameters: "/del {app}"

   115 

   116 [Code]

   117 procedure Touch(fn: String);

   118 begin

   119   SaveStringToFile(ExpandConstant(fn), '', False);

   120 end;